Email HTML

Resolvendo o Problema

Passo 1 - Primeiramente criaremos uma Function para importar a tabela da planilha na formatação HTML.

1. Iniciamos definindo o tipo de dado de saída da função

   Function TaBeLaHTML()as String
   

2. Declaramos as variáveis

   Dim UltColuna As Range
   Dim UltLinha As Range
   Dim i As Range
   Dim j As Range
   Dim TabHtml As String
   

3. A variável TabHtml será uma "String" com o conteúdo da tabela em linguagem HTML. Iremos acrescentando os dados a esta variável a medida que a função for sendo executada, começamos com a tag de abertura da tabela HTML

   TabHtml = "<table>"
   

4. Definimos o intervalo para primeira coluna da tabela

   Set UltLinha = Range("A2", Range("A2").End(xlDown))
   

5. Criamos um loop For Each para cada célula dentro do intervalo

   For Each i In UltLinha
   

6. Criamos uma condicional If para adicionar o estilo caso seja a primeira célula da tabela.

   If i = Range("A2") Then
       TabHtml = TabHtml & "<tr style=""color:green;font-size:16px;"">"
   Else
       TabHtml = TabHtml & "<tr>"
   End If
   

7. Definimos o intervalo da linha em função da posição do contador do loop anterior

   Set UltColuna = Range(i, i.End(xlToRight))
   

8. Criamos um segundo loop dentro do primeiro que irá adicionar à variável TabHtml os valores de todas as colunas de uma determinada linha

   For Each j In UltColuna
       TabHtml = TabHtml & "<td>" & j.Value & "</td>"
   Next j
   

9. Fechamos a tag da linha em linguagem HTML e iniciamos a próxima

       TabHtml = TabHtml & "</tr>"
   Next i
   

10. Concluídos os loops, fechamos a tabela e atribuímos o resultado da função à tabela HTML (o retorno TaBeLaHTML)

    TabHtml = TabHtml & "</table>"
    
    TaBeLaHTML = TabHtml
    

Passo 2 - Agora que já temos a tabela formatada e pronta para ser utilizada no email, criamos uma subrotina para o envio.

1. Declaramos as variáveis

   Dim OlOut As Object
   Dim OlMail As Object
   Dim Result As String
   

2. Definimos a variável OlOut como o OutLook e OlMail como a criação de um email do Outlook

   Set OlOut = CreateObject("OutLook.Application")
   Set OlMail = OlOut.CreateItem(0)
   

3. Determinamos o tipo de email, o corpo do texto, o título, o destinatário, e enviamos (note que para o corpo do email chamamos a função que criamos previamente).

   With OlMail
       .Bodyformat = 2
       .Display
       .HTMLbody = "<p>Caros,</p>" & "Segue a tabela atualizada com as cotações do plano de saúde por faixa etária.<br><br>" & TaBeLaHTML & .HTMLbody
       .Subject = "Email HTML"
       '.To = "fulano@gmail.com"
       '.Attachments.add "D:\Documents\Cotacao.xlsm"
       '.Send
   
   End With
   

Cuidado: É muito comum enviar emails com erros. Por isso, cheque muito bem seu código antes de colocar o .Send

Código Consolidado

    Sub Resolucao()

    Dim OlOut As Object
    Dim OlMail As Object
    Dim Result As String

    Set OlOut = CreateObject("OutLook.Application")
    Set OlMail = OlOut.CreateItem(0)

    With OlMail
        .Bodyformat = 2
        .Display
        .HTMLbody = "<p>Caros,</p>" & "Segue a tabela atualizada com as cotações do plano de saúde por faixa etária.<br><br>" & TaBeLaHTML & .HTMLbody
        .Subject = "Email HTML"
        '.To = "fulano@gmail.com"
        '.Attachments.add "D:\Documents\Cotacao.xlsm"
        '.Send

    End With

    End Sub

    Function TaBeLaHTML()

    Dim UltColuna As Range
    Dim UltLinha As Range
    Dim i As Range
    Dim j As Range
    Dim TabHtml As String

    TabHtml = "<table>"

    Set UltLinha = Range("A2", Range("A2").End(xlDown))

    For Each i In UltLinha
        If i = Range("A2") Then
            TabHtml = TabHtml & "<tr style=""color:green;font-size:16px;"">"
        Else
        TabHtml = TabHtml & "<tr>"
        End If

        Set UltColuna = Range(i, i.End(xlToRight))

        For Each j In UltColuna
            TabHtml = TabHtml & "<td>" & j.Value & "</td>"
        Next j

        TabHtml = TabHtml & "</tr>"

    Next i

    TabHtml = TabHtml & "</table>"
    TaBeLaHTML = TabHtml

    End Function